Программирование на языке Assembler в FASM — Архив WASM.RU

Введение

В начале было слово... Если точнее то было просто предложение от Kinder-а написать статью посвящённую макросам в FASM. Я согласился попробовать, но рассматривать макросы отдельно от синтаксиса как-то не очень правильно, а синтаксис без примеров разобрать сложно и в результате получилось сочинение о том как писать программы в FASM.

В этом сочинении будут рассмотрены основные моменты отличающие FASM от других компиляторов, правила по которым пишутся макросы и форматы выходных файлов создаваемые FASM-ом. Так же в рамках данного сочинения мы создадим несколько контролов в виде макросов.

Основы.

Данный раздел является вольным
пересказом соответствующего раздела
руководства, поставляемого с
компилятором.

Данная статья посвящена использованию макросов в компиляторе FASM. Для начала вопрос: "Что такое макрос?" (поскольку я не могу услышать Ваш ответ прямо сейчас, когда пишу эту статью, отправляйте свои ответы мне по электронной почте, если Ваше мнение отличается от моего мнения).

Макрос - это инструкция препроцессору компилятора развернуть, встретившееся в коде программы, имя макроса (возможно с параметрами) в последовательность строк кода ассемблера с использованием переданных параметров (если таковые заданы).

Далее предлагаю Вам ознакомиться с основными директивами, используемыми внутри определений макросов.

Внутри определений макросов можно использовать инструкции if и else при этом каждая инструкция if должна закрываться инструкцией end if. Пример из руководства, поставляемого вместе с компилятором:

Код (Text):

1.  
2. macro mov op1,op2
3. {
4. if op1 in <ds,es,fs,gs,ss> & op2 in <cs,ds,es,fs,gs,ss>
5.    push op2
6.    pop op1
7. else
8.    mov op1,op2
9. end if
10. }

Этот макрос является расширением инструкции процессора mov. В данном случае если оба операнда макроса являются сегментными регистрами используется связка "push - pop", в любом другом случае используется стандартная инструкция "mov op1,op2". Оператор in позволяет проверить соответствие операнда нескольким значениям в угловых скобках.

Можно ещё более расширить эту инструкцию для пересылки трёх значений второго в первый, а третьего во второй:

Код (Text):

1.  
2. macro mov op1,op2,op3
3. {
4.    if arg3 eq
5.       mov op1,op2
6.    else
7.       mov op1,op2
8.       mov op2,op3
9.    end if
10. }

В данном случае нас интересует инструкция eq, которая позволяет проверить эквивалентен ли операнд какому либо значению, в нашем случае мы проверяем его отсутствие, и если он отсутствует, то подставляется ветвь if иначе подставляется ветвь else.

Директива purge позволяет отменить последнее определение макроса.

Кроме уже изложенного в определение макроса можно передавать заранее неизвестное количество операндов (пар операндов и т.д.), для этого необходимо заключить операнды, количество которых заранее неизвестно, в квадратные скобки. Например для вызова процедур написан макрос STDCALL:

Код (Text):

1.  
2. macro stdcall proc,[arg];
3.  { reverse
4.     push arg
5.    common
6.     call proc }

Операндами этого макроса служат один обязательный (proc) и несколько необязательных параметров (arg). Директива reverse сообщает препроцессору, что следующие строки необходимо повторить столько раз, сколько параметров arg передано макросу начиная с последнего параметра. Директива common сообщает препроцессору, что следующие строки необходимо повторить только один раз. Директива forward сообщает препроцессору, что следующие строки необходимо повторить столько раз, сколько параметров arg передано макросу начиная с первого параметра. Действие директив common, forward и reverse заканчивается другой директивой common, forward или re-verse соответственно или закрывающейся фигурной скобкой. Если ни одна из этих директив не встречается в определении макроса, то макрос развернётся для всех параметров начиная с первого. Неизвестное количество параметров можно передать и другому макросу:

Код (Text):

1.  
2. macro invoke proc,[arg]        
3.  { common
4.     if ~ arg eq
5.      stdcall [proc],arg
6.     else
7.      call [proc]
8.     end if }

В этом примере при выполнении ветви if в макрос stdcall кроме параметра [proc] передаются все полученные параметры arg.

Внутри макроопределения может использоваться оператор #, который может использоваться для составления операторов ассемблера, например условного перехода:

Код (Text):

1.  
2. macro jif op1,cond,op2,label
3. {
4.   cmp op1,op2
5.   j#cond label
6. }

При выполнении макроса jif ax,ae,10h,exit макрос будет развёрнут в следующую конструкцию:

Код (Text):

1.  
2. cmp ax,10h
3. jae exit

Так же этот оператор можно использовать и для составления имён переменных или макросов внутри макроопределений:

Код (Text):

1.  
2. macro ver [name]
3. {
4.  name#.mas: times 10 db 0
5. }

Теперь при вызове данного макроса в секции данных

Код (Text):

1.  
2. ver Chif,Rab

Мы будем иметь два массива из 10 байт каждый, с именами Chif.mas и Rab.mas.

Аналогично можно создать и переменные и макросы внутри определения макроса. Однако определить макрос внутри макроса обычным путём:

Код (Text):

1.  
2. Macro mac1
3. {
4.  macro mac2
5. {
6.   ... ... ...
7. }
8. }

препроцессор не позволит использовать данную конструкцию, выход в использовании директивы fix она эквивалентна директиве equ, но препроцессор обрабатывает fix позже чем equ, что и позволяет использовать подобную конструкцию:

Код (Text):

1.  
2.  Macro mac1
3. {
4.  macro mac2
5. m_
6.   ... ... ...
7. _m
8. }
9. m_ fix {
10. _m fix }

Синтаксис компилятора ФАСМ несколько отличается от синтаксиса других компиляторов, но отличия незначительны и в основном касаются макроязыка.

Средства макроязыка мы рассмотрим ниже, здесь же я хотел бы отметить только то, что передача адреса переменной производится указанием имени переменной без каких либо скобок или префиксов, а её содержимого написанием имени переменной в квадратных скобках.

mov eax,var; записываем в регистр еах адрес переменной var mov eax,[var]; записываем в регистр еах значение переменной var

Структура каркасного приложения на ФАСМ-е

В этой части мы рассмотрим, основы
синтаксиса данного компилятора и
рассмотрим каркасные приложения для
основных форматов исполняемых файлов.

Итак, что необходимо для работающего приложения?

Во-первых мы должны указать компилятору какого формата должен быть создаваемый файл. Это делается директивой format после, которой следует указание форматов:

• PE формат исполняемых файлов Windows. Далее должно следовать уточнение GUI (графический интерфейс), console (консольное приложение) и native (если Вы знаете, что это такое сообщите мне). Если выбран графический интерфейс, то следует также указать версию графического интерфейса 4.0, а так же зарезервированное слово DLL, если собирается динамическая библиотека.
• MZ формат исполняемых файлов MS DOS.
• COFF или MS COFF (для линковки продуктами Microsoft)для создания объектного файла, который в дальнейшем будет линковаться к другому проекту или к ресурсам.
• ELF формат для создания исполняемых файлов UNIX подобных систем (Linux).

Как Вы наверно поняли, я не знаком с файлами ELF типа и в данной статье мы не будем его рассматривать. Если директива format не указана, компилятор соберёт файл в формате com.

После указания формата выходного файла мы должны указать компилятору точку начала программы. Это делается с помощью директивы entry после которой указывается метка, с которой начинается код программы. Например entry start.

Так же, в случае необходимости, мы должны указать на начало секций данных, кода, импорта, экспорта или ресурсов. Для этого существует директива section, после которой в кавычках следует название секции, далее без скобок тип секции (данные или код) и атрибуты (запись, чтение исполняемый код). Более подробно когда какие атрибуты указывать Вы прочитаете ниже т.к. для разных форматов выходных файлов эти атрибуты отличаются.

Форматы PE исполняемых файлов Windows.
Консольные приложения

Консольное приложение может использовать все функции API предоставляемые Windows, но работать с такой программой пользователь может только через командную строку.

Вот простой пример консольного приложения:

Код (Text):

1.  
2. format PE console
3. entry start
4. include 'include\kernel.inc'
5. include 'include\macro\stdcall.inc'
6. include 'include\macro\import.inc'
7. section '.data' data readable writeable
8.   h4    db Консоль'
9.   w1 dd 0
10.   output dd 0
11.   input dd 0
12.   _class db 'FCAPTION',0
13.   podskazka db 'Консоль',0
14. section '.code' code readable executable
15.   start:
16.     invoke    GetStdHandle,STD_OUTPUT_HANDLE
17.     mov       [output],eax
18.     invoke    GetStdHandle,STD_INPUT_HANDLE
19.     mov       [input],eax
20.     invoke    WriteConsole,[output],h4,7,w1,0
21.     invoke    ReadConsole,[input],_class,2,w1,0
22.     invoke  ExitProcess,0
23. section '.idata' import data readable
24.  
25.   _library kernel32,'KERNEL32.DLL',\
26.          user32,'USER32.DLL',\
27.          gdi32,'GDI32.DLL',\
28.          advapi32,'ADVAPI32.DLL',\
29.          comctl32,'COMCTL32.DLL',\
30.          comdlg32,'COMDLG32.DLL',\
31.          shell32,'SHELL32.DLL',\
32.          wsock32,'WSOCK32.DLL';,\
33.      include 'C:\FASM135\147\INCLUDE\apia\kernel32.inc'
34.      include 'C:\FASM135\147\INCLUDE\apia\user32.inc'
35.      include 'C:\FASM135\147\INCLUDE\apia\gdi32.inc'
36.      include 'C:\FASM135\147\INCLUDE\apia\advapi32.inc'
37.      include 'C:\FASM135\147\INCLUDE\apia\comctl32.inc'
38.      include 'C:\FASM135\147\INCLUDE\apia\comdlg32.inc'
39.      include 'C:\FASM135\147\INCLUDE\apia\shell32.inc'
40.      include 'C:\FASM135\147\INCLUDE\apia\wsock32.inc'

В данном примере создаётся три секции: данных, кода и секция импортируемых функций. Секцию импорта я создаю при помощи макроса _library, в стандартной поставке такого макроса нет, но если написать без подчёркивания перед library то всё скомпилируется правильно. Причина проста, я пользуюсь FASM-ом с версии 1.35, а тогда такого макроса еще не было (а сам я ещё не смог бы его написать) и для совместимости с ранее написанными программами я включил два варианта этого макроса. В ранней версии, необходимо было записывать все используемые в приложении функции вручную, теперь же работу по подключению только используемых функций берёт на себя компилятор, хотя за такое удобство приходится платить некоторым увеличением времени компиляции. Более подробно о принципе работы этого и других макросов будет написано в соответствующем разделе ниже.

Название секции импорта ".idata", хотя название можно изменить и это не повлияет на работоспособность программы, т.к. мы указали назначение этой секции import data, далее следует указание атрибутов, в данном случае readable, что означает для чтения и этого достаточно, если Вы не собираетесь менять содержимое этой секции.

Следующей рассмотрим секцию данных. У нас секция данных имеет название ".data", далее следует указание назначения секции data, что означает секцию данных, атрибуты указаны readable writeable, т.е. эта область памяти будет доступна для чтения и записи. Если указать только первый атрибут (readable) при выполнении программы произойдёт ошибка "Программа выполнила недопустимую операцию".

Последней рассмотрим секцию кода, она имеет название ".code" назначение секции code, т.е. исполняемая часть программы, атрибуты readable executable, что означает, что из секции кода мы можем читать данные (под данными может подразумеваться и коды инструкций и определённые в этой секции данные) и можем выполнять содержимое этой секции.

Кроме рассмотренных секций, консольное приложение может иметь секции экспортируемых функций и секцию ресурсов.

Это пожалуй всё, что необходимо знать для начала о консольных приложениях. Да ещё я считаю лишний раз напомнить, что хоть консольное приложение и напоминает внешне программы DOS-а, использование прерываний в нём не допускается т.к. это всё же приложение Windows, естественно выполняться такое приложение может только в Windows.

Графическое приложение

Графические приложения Windows это оконные приложения, такие как Word, Excel, Notepad и т.д.

В отличии от консольных приложений, GUI приложения должны содержать как минимум одну процедуру обработки сообщений, приходящих к окну. Вот простой пример оконного приложения:

Код (Text):

1.  
2. format PE GUI 4.0
3. entry start
4. include 'include\kernel.inc'
5. include 'include\user.inc'
6. include 'include\macro\stdcall.inc'
7. include 'include\macro\import.inc'
8. include 'include\macro\resource.inc'
9. section '.data' data readable writeable
10.   Avtor db 'Автор:Пороткин Алексей Сергеевич',0
11.   Progr db 'Программа построения графиков',0
12.   MyMessage db 'Отклик',0
13.   hinstance dd 0
14.   h4    db 'Сообщение',0
15.   w1 dd 0
16.   msg MSG
17.   wc WNDCLASS
18.   pt dd 0
19.   hDC dd 0
20.   ws equ  WS_VISIBLE+WS_CAPTION+WS_MINIMIZEBOX+WS_SYSMENU
21.   _class db 'FCAPTION',0
22.   podskazka db 'Графическое приложение',0
23. section '.code' code readable executable
24.   start:
25.     invoke  GetModuleHandle,0
26.     mov [hinstance],eax
27.     invoke  LoadIcon,eax,17
28.     mov [wc.hIcon],eax
29.     invoke  LoadCursor,0,IDC_ARROW
30.     mov [wc.hCursor],eax
31.     mov [wc.style],0
32.     mov [wc.lpfnWndProc],WindowProc
33.     mov [wc.cbClsExtra],0
34.     mov [wc.cbWndExtra],0
35.     mov eax,[hinstance]
36.     mov [wc.hInstance],eax
37.     mov [wc.hbrBackground],6;COLOR_BTNFACE+1
38.     mov [wc.lpszMenuName],0
39.     mov [wc.lpszClassName],_class
40.     invoke  RegisterClass,wc
41.     invoke  CreateWindowEx,0,_class,podskazka,ws,10,10,680,450,NULL,NULL,[hinstance],NULL
42.  
43.   msg_loop:
44.     invoke  GetMessage,msg,NULL,0,0
45.     or  eax,eax
46.     jz  end_loop
47.     invoke  TranslateMessage,msg
48.     invoke  DispatchMessage,msg
49.  
50.     jmp msg_loop
51.  
52.   end_loop:
53.     invoke  ExitProcess,[msg.wParam]
54. ;include 'include\macro\lib.asm'
55. proc WindowProc, hwnd,wmsg,wparam,lparam
56.     enter
57.     push    ebx esi edi
58.           cmp   [wmsg],WM_DESTROY
59.     je  wmdestroy
60.     cmp [wmsg],WM_CREATE
61.     je  wmcreate
62.   defwndproc:
63.     invoke  DefWindowProc,[hwnd],[wmsg],[wparam],[lparam]
64.     jmp finish
65. wmcreate:
66.    
67.     jmp ext
68.  
69.   wmdestroy:
70.     invoke  PostQuitMessage,0
71. ext:    xor eax,eax
72.   finish:
73.     pop edi esi ebx
74.     return
75. section '.idata' import data readable writeable
76.   library kernel,'KERNEL32.DLL',\
77.       user,'USER32.DLL'
78.       ;shell,'SHELL32.DLL',\
79.       ;gdi,'gdi32.dll'
80.   kernel:
81.   import GetModuleHandle,'GetModuleHandleA',\
82.      ExitProcess,'ExitProcess',lstrcpy,'lstrcpyA',\
83.      FindFirstChangeNotification,'FindFirstChangeNotificationA',\
84.      FindNextChangeNotification,'FindNextChangeNotification',\
85.      FindCloseChangeNotification,'FindCloseChangeNotification'
86.   user:
87.   import RegisterClass,'RegisterClassA',\
88.      CreateWindowEx,'CreateWindowExA',\
89.      DefWindowProc,'DefWindowProcA',\
90.      SetWindowLong,'SetWindowLongA',\
91.      RedrawWindow,'RedrawWindow',\
92.      GetMessage,'GetMessageA',\
93.      MessageBox,'MessageBoxA',\
94.      TranslateMessage,'TranslateMessage',\
95.      DispatchMessage,'DispatchMessageA',\    
96.      SendMessage,'SendMessageA',\
97.      LoadCursor,'LoadCursorA',\
98.      LoadIcon,'LoadIconA',\
99.      LoadMenu,'LoadMenuA',\
100.      SetMenu,'SetMenu',\
101.      InsertMenu,'InsertMenuA',\
102.      CreateMenu,'CreateMenu',\
103.      DrawMenuBar,'DrawMenuBar',\     
104.      PostQuitMessage,'PostQuitMessage',\
105.      FindWindow,'FindWindowA',\
106.      FindWindowEx,'FindWindowExA',\
107.      LoadImageA,'LoadImageA',\
108.      CreatePopupMenu,'CreatePopupMenu',\
109.      AppendMenu,'AppendMenuA',\
110.      DestroyMenu,'DestroyMenu',\
111.      GetCursorPos,'GetCursorPos',\
112.      SetForegroundWindow,'SetForegroundWindow',\
113.      TrackPopupMenu,'TrackPopupMenu',\
114.      PostMessage,'PostMessageA',\
115.      DestroyWindow,'DestroyWindow',\
116.      ShowWindow,'ShowWindow',GetDC,'GetDC'
117. section '.rsrc' resource data readable
118.   directory   RT_ICON,icons,\
119.         RT_GROUP_ICON,group_icons
120.   icons:
121.   resource 1,LANG_NEUTRAL,icon_data
122.   group_icons:
123.   resource 17,LANG_NEUTRAL,main_icon
124.   icon main_icon,icon_data,'mp\lv\lv.ico'

Так же, как и в примере с консольным приложением, в первой строке указана директива format PE, но вместо console, как в предыдущем примере, дано указание GUI 4.0 компилятору собирать приложение с графическим интерфейсом версии 4.0.

Приложение из нашего примера ничего полезного не делает, оно просто создаёт окно, которое реагирует только на нажатие двух системных кнопок в верхнем правом углу окна "Свернуть" и "Закрыть". Приложение содержит секции данных, кода, импорта и ресурсов. После указания точки входа в программу entry start подключаются файлы содержащие макросы и определения констант и структур Windows. Затем следует секция данных, определение которой дано в предыдущем разделе, и секция кода. В секции кода мы получаем хендл нашего модуля (GetModuleHandle), загружаем иконку (LoadIcon), определённую в секции ресурсов, загружаем стандартный курсор Windows (LoadCursor) и заполняем структуру wc для дальнейшей регистрации класса нашего окна (RegisterClass). После регистрации класса окна мы создаём окно зарегистрированного класса (CreateWindowEx). В структуре wc имеется член .lpfnWndProc, в который мы записываем адрес начала процедуры обработки событий окна WindowProc. Далее следует цикл обработки сообщений, посылаемых окну системой Windows.

Процедура обработки сообщений получает от Windows четыре параметра:

proc WindowProc, hwnd, wmsg, wparam, lparam

где:

hwnd - хендл нашего окна
wmsg - код сообщения, которое Windows послало нашему окну
wparam и lparam - уточняющие параметры посланного сообщения.

proc это не директива компилятора, а макрос содержащий, часть пролога процедуры. Он определён следующим образом:

Код (Text):

1.  
2. macro proc name,[arg]
3.  { common
4.     name:
5.     virtual at ebp+8
6.     if ~ arg eq
7.    forward
8.      local ..arg
9.      ..arg dd ?
10.      arg equ ..arg
11.    common
12.      end if
13.      ..ret = $ - (ebp+8)
14.     end virtual
15.     local ..dynamic_data,..dynamic_size
16.     dynamic_data equ ..dynamic_data
17.     dynamic_size equ ..dynamic_size
18.     virtual at ebp - dynamic_size
19.      dynamic_data: }

Таким образом следующая строка proc Win,param будет развёрнута в следующую конструкцию:

Код (Text):

1.  
2.     Win:
3.     virtual at ebp+8
4.         local ..param
5.         ..param dd ?
6.         param equ ..param
7.         ..ret = $ - (ebp+8)
8.     end virtual
9.     local ..dynamic_data,..dynamic_size
10.     dynamic_data equ ..dynamic_data
11.     dynamic_size equ ..dynamic_size
12.     virtual at ebp - dynamic_size
13.      dynamic_data: }

Более подробно это означает, что мы определяем метку Win, которая означает начало процедуры. В следующей строке записана директива virtual at ebp+8, которая должна заканчиваться директивой end virtual. Внутри этого определения помещаются переменные, которые будут размещаться с адреса указанного после at, в нашем примере это ebp+8. Это означает, что в нашем примере запись "mov param,eax" будет заменена на "mov [ebp+8],eax". Если бы в определении процедуры было две или более переменных, то адрес каждой последующей переменной увеличивался бы на размер предыдущей переменной. Таким образом:

Код (Text):

1.  
2. virtual at ebp+8
3.    param1 dd ?
4.    param2 db ?
5.    param3 dd ?
6. end virtual

определит три переменные с адресами

Код (Text):

1.  
2. param1 = ebp+8+0,
3. param2 = ebp+8+4,
4. param2 = ebp+8+5.

У некоторых читателей может возникнуть вопрос: "А зачем все эти пляски?". Ответ прост: регистр ebp указывает на вершину стека и все переменные, передаваемые в процедуру, находятся выше (в смысле в памяти с адресами больше чем вершина стека т.к. вершина стека сдвигается вниз когда в стек помещаются данные и вверх, когда данные из стека изымаются) текущей вершины стека.

Первой, в определении переменных внутри virtual - end virtual записана директива local, которая указывает компилятору, что следующие за ней через запятую метки, локальны в данном макросе.

Последней, внутри описания виртуальных переменных, следует определение макропеременной ..ret = $ - (ebp+8), которая фактически содержит количество переданных процедуре байт параметров. Она используется при написании эпилога процедуры для очистки стека при возврате управления инструкции, следующей за вызовом данной процедуры.

После определения виртуальных переменных, передаваемых процедуре в качестве параметров, определяются локальные макропеременные, которые используются во второй части пролога процедуры. Я уже несколько раз использовал термин - макропеременная. Макропеременная отличается от переменных, используемых в программе, тем, что она существует только во время компиляции и используется как константа, которая может иметь разные значения в разных частях программы.

После определения макропеременных начинается блок определения виртуальных переменных, однако переменных в этом макросе нет. После макроса proc необходимо ставить макрос enter, который содержит заключительную часть пролога, а между ними могут располагаться локальные переменные. Для того, что бы имена переменных были локальными перед ними ставится точка. Например .param. Макрос enter определён следующим образом:

Код (Text):

1.  
2. macro enter            
3. {  dynamic_size = $ - dynamic_data
4.    end virtual
5.    enter dynamic_size,0
6. }

Таким образом dynamic_size - это размер памяти отведённой под локальные переменные. Последняя инструкция, в прологе процедуры, enter dynamic_size,0. Это единственная строка, которая попадёт в исполняемый код программы. Завершаться процедура должна макросом return, который определён следующим образом:

Код (Text):

1.  
2. macro return               
3. { leave
4.    ret ..ret }

Полагаю здесь не должно быть сложностей с пониманием макроса.

Процедура должна правильно обрабатывать поступившие сообщения. Те сообщения, которые мы хотим обработать сами, выделяются в первых строках процедуры и управление передаётся на те участки кода, которые должны производить необходимые действия, а те сообщения, которые нам нет необходимости обрабатывать, мы доверяем обработать системе Windows (Def-WindowProc).

Хочу обратить Ваше внимание на то, что в данной программе используются глобальные метки (wmdestroy, wmcreate, defwndproc), что не очень удобно в программах содержащих несколько процедур (большинство оконных процедур обрабатывают одни и те же сообщения), поэтому рекомендуется внутри процедур использовать локальные метки (.wmdestroy, .wmcreate, .defwndproc).

Теперь пришло время посмотреть на секцию импорта. Она отличается от рассмотренной в предыдущем разделе здесь мы используем макрос library, который определён следующим образом:

Код (Text):

1.  
2. macro library [label,string]
3.  { forward
4.     local _label
5.     dd 0,0,0,rva _label,rva label
6.    common
7.     dd 0,0,0,0,0
8.    forward
9.     _label db string,0 }

Для того, чтобы было более понятно вспомним, как в нашем примере используется этот макрос:

Код (Text):

1.  
2. library kernel,'KERNEL32.DLL',\
3.       user,'USER32.DLL'

Таким образом, макрос library создаёт заголовок таблицы импорта, вначале записывая смещение названия библиотеки DLL, а затем смещение, с которого начинаются имена импортируемых функций.

Далее следуют макросы import, определённые следующим образом:

Код (Text):

1.  
2. macro import [label,string]
3.  { forward
4.     local _label
5.     label dd rva _label
6.    common
7.     dd 0
8.    forward
9.     _label dw 0
10.        db string,0 }

Он создаёт тело таблицы импорта для каждой из импортируемых библиотек.

Вначале создавая таблицу смещений имён импортируемых функций, а затем записывая имена импортируемых функций. Более подробно о структуре PE-файла Вы должны прочитать в соответствующей литературе (например в туториалах, которые написал Iczelion).

После таблицы импорта создаётся таблица ресурсов:

Код (Text):

1.  
2. section '.rsrc' resource data readable
3.   directory   RT_ICON,icons,\
4.         RT_GROUP_ICON,group_icons
5.   icons:
6.   resource 1,LANG_NEUTRAL,icon_data
7.   group_icons:
8.   resource 17,LANG_NEUTRAL,main_icon
9.   icon main_icon,icon_data,'mp\lv\lv.ico'

В нашем примере мы используем только одну иконку.

Динамические библиотеки (DLL)

Последним в данном разделе рассмотрим простую динамическую библиотеку.

Динамическая библиотека - это приложение GUI, который может содержать как исполняемый код, так и ресурсы. Это приложение не предназначено для самостоятельного запуска, оно используется другими приложениями для хранения часто используемых процедур, шрифтов и многого другого.

Мы рассмотрим создание динамической библиотеки на примере процедуры, возвращающей строку, содержащую текущую дату. Мы создадим два модуля один файл динамической библиотеки (dll2.dll) и файл использующий созданную нами библиотеку (usedll.exe).

Вот файл динамической библиотеки:

Код (Text):

1.  
2. format PE GUI 4.0 DLL
3. entry DllEntryPoint
4. include 'include\kernel.inc'
5. include 'include\user.inc'
6. include 'include\macro\stdcall.inc'
7. include 'include\macro\import.inc'
8. include 'c:\fasm135\include\lib\strings.mac'
9. include 'include\macro\export.inc'
10. section '.data' data readable writeable
11.   _outs: times 60 db 0
12.   Date SYSTEMTIME
13.   day db 'День:',0
14.   mon db ' Месяц:',0
15.   year db ' Год:',0
16.   h4: times 20 db 0
17.   DllState db 'Состояние библиотеки DLL',0
18.   DllStart db 'Загружена',0
19.   DllStop  db 'Выгружена',0
20.   bf: times 20 db 0
21. section '.code' code readable executable
22. proc DllEntryPoint, hinstDLL,fdwReason,lpvReserved
23.     enter
24.     cmp       [fdwReason],DLL_PROCESS_ATTACH
25.     je    .start
26.     cmp       [fdwReason],DLL_PROCESS_DETACH
27.     je    .stop
28.     jmp   .stp
29.     .start:
30.     invoke    MessageBox,0,DllStart,DllState,MB_OK
31.     jmp   .stp
32.     .stop:
33.     invoke    MessageBox,0,DllStop,DllState,MB_OK
34.     jmp   .stp
35.    .stp:   
36.     mov eax,TRUE
37.     return
38. proc Wind
39. enter
40.     push    ebx esi edi
41.     invoke   GetLocalTime,Date
42.     mov  ebx,_outs
43.     StringCopyHTML ebx,day
44.     add  ebx,eax
45.     xor  eax,eax
46.     mov  ax,[Date.wDay]
47.     stdcall  IntToString,h4,eax
48.     StringCopyHTML ebx,h4
49.     add  ebx,eax
50.     StringCopyHTML ebx,mon
51.     add  ebx,eax
52.     xor  eax,eax
53.     mov  ax,[Date.wMonth]
54.     stdcall  IntToString,h4,eax
55.     StringCopyHTML ebx,h4
56.     add  ebx,eax
57.     StringCopyHTML ebx,year
58.     add  ebx,eax
59.     xor  eax,eax
60.     mov  ax,[Date.wYear]
61.     stdcall  IntToString,h4,eax
62.     StringCopyHTML ebx,h4
63.     mov  eax,_outs
64.     pop edi esi ebx
65. return
66. proc IntToString,lpOutBuf,var
67.    len dd 0
68.        enter
69.        push ebx esi edx ecx esi
70.        ;jmp .ex
71.        cmp  [var],0
72.        jne  .norr
73.        mov   eax,[lpOutBuf]
74.        mov   dx,030h
75.        mov   [eax],dx
76.        jmp  .ex
77.        .norr:
78.        mov  eax,10
79.        mov  [len],eax  
80.        xor eax,eax
81.        xor edx,edx
82.        xor ecx,ecx
83.        mov  esi,bf
84.        mov  eax,[var]
85.        cmp eax,0
86.        jne .ll
87.        mov eax,48
88.        mov [esi],al
89.        inc esi
90.        jmp .ext
91.  .ll:  
92.        div  [len]
93.        add  dl,48
94.        mov  [esi],dl
95.        inc  esi
96.        inc ecx
97.        xor  edx,edx
98.        cmp  eax,0
99.        jne   .ll
100.  .ext:
101.       mov [esi],dl
102.       mov eax,[lpOutBuf]
103.       cmp ecx,0
104.       je .ex
105.   .l: dec esi
106.       mov dl,[esi]
107.       mov [eax],dl
108.       inc  eax
109.       dec  ecx
110.       cmp  ecx,0
111.       jne .l
112.       mov  dl,0
113.       mov  [eax],dl
114.  .ex:     pop   esi ecx edx esi ebx
115. return
116. section '.idata' import data readable writeable
117.      _library kernel32,'KERNEL32.DLL',\
118.          user32,'USER32.DLL';,\
119.      include 'C:\FASM135\147\INCLUDE\apia\kernel32.inc'
120.      include 'C:\FASM135\147\INCLUDE\apia\user32.inc'
121. section '.edata' export data readable
122.   export 'dll2.dll',Wind,'Wind'
123. section '.reloc' fixups data discardable

Первые строки format PE GUI 4.0 DLL и entry DllEntryPoint указывают компилятору создать РЕ-файл динамической библиотеки с точкой входа на метке DllEntryPoint.

Как Вы могли заметить динамическая библиотека практически ни чем не отличается от обычной программы Windows, кроме того, что входная процедура вызывается системой в четырёх случаях:

• Когда динамическая библиотека загружается в адресное пространство процесса (параметр fdwReason = DLL_PROCESS_ATTACH = 1);
• Когда динамическая библиотека выгружается из адресного пространства процесса (параметр fdwReason = DLL_PROCESS_ DETACH = 0);
• Когда создается новый поток в рамках динамической библиотеки (параметр fdwReason = DLL_ THREAD_ATTACН = 2);
• Когда разрушается (прекращается) поток в рамках динамической библиотеки (параметр fdwReason = DLL_ THREAD_DETACH = 3).

В обработке стартовой процедуры мы определяем значение параметра fdwReason и если динамическая библиотека была загружена или выгружена выдаём соответствующее сообщение.

В конце файла мы создаём секцию экспорта нашей библиотеки:

Код (Text):

1.  
2. section '.edata' export data readable
3.   export 'dll2.dll',Wind,'Wind'
4. section '.reloc' fixups data discardable

В таблице мы задаём имя файла динамической библиотеки и имена экспортируемых процедур.

Макрос export определён следующим образом:

Код (Text):

1.  
2. macro export dllname,[label,string]
3. { common
4.     local module,addresses,names,ordinal,count
5.     count = 0
6.    forward
7.     count = count+1
8.    common
9.     dd 0,0,0,rva module,1
10.     dd count,count,rva addresses,rva names,rva ordinal
11.     addresses:
12.    forward
13.     dd rva label
14.    common
15.     names:
16.    forward
17.     local name
18.     dd rva name
19.    common
20.     ordinal: count = 0
21.    forward
22.     dw count
23.     count = count+1
24.    common
25.     module db dllname,0
26.    forward
27.     name db string,0 }

Сперва, объявляются локальные метки и подсчитывается количество экспортируемых процедур:

Код (Text):

1.  
2.   common
3.     local module,addresses,names,ordinal,count
4.     count = 0
5.    forward
6.     count = count+1
7.    common

Затем заносится смещение RVA имени библиотеки:

Код (Text):

1.  
2.     dd 0,0,0,rva module,1

Следующая строка заносит общее количество экспортируемых функций, количество функций экспортируемых по имени (при использовании этого макроса все функции экспортируются по имени), смещение начала массива смещений функций, смещение начала массива смещений имен экспортируемых функций и смещение массива смещений ординалов функций.

Код (Text):

1.  
2.     dd count,count,rva addresses,rva names,rva ordinal

Далее объявляется метка начала массива смещений экспортируемых функций и создаётся массив их смещения:

Код (Text):

1.  
2. addresses:
3.    forward
4.     dd rva label

Следом объявляется метка начала массива смещений имён экспортируемых функций и создаётся сам массив:

Код (Text):

1.  
2. common
3.     names:
4.    forward
5.     local name
6.     dd rva name

Затем объявляется метка начала массива смещений ординалов функций и создаётся массив ординалов экспортируемых функций:

Код (Text):

1.  
2. common
3.     ordinal: count = 0
4.    forward
5.     dw count
6.     count = count+1

Ну и в конце макроса записывается имя динамической библиотеки и создаётся массив имен экспортируемых функций:

Код (Text):

1.  
2. common
3.     module db dllname,0
4.    forward
5.     name db string,0

Для более подробного ознакомления со структурой секции экспорта необходимо читать специальную литературу по структуре РЕ - файлов.

Теперь давайте посмотрим, на программу вызывающую нашу динамическую библиотеку:

Код (Text):

1.  
2. format PE GUI 4.0
3. entry start
4. include 'include\kernel.inc'
5. include 'include\user.inc'
6. include 'include\macro\stdcall.inc'
7. include 'include\macro\import.inc'
8. section '.data' data readable writeable
9.   Avtor db 'Автор:Пороткин Алексей Сергеевич',0
10.   podskazka db 'Функция Wind возвратила указатель на строку:',0
11. section '.code' code readable executable
12.   start:
13.    invoke Wind
14.    invoke MessageBox,0,eax,podskazka,MB_OK
15.    invoke ExitProcess,0
16. section '.idata' import data readable writeable
17.   library kernel,'KERNEL32.DLL',\
18.       user,'USER32.DLL',\
19.       MyDll,'C:\FASM135\mp\Dll2\Dll2.DLL'
20.   kernel:
21.   import     ExitProcess,'ExitProcess'
22.   user:
23.   import     MessageBox,'MessageBoxA'
24.  MyDll:
25.   import Wind,'Wind'

Обычное графическое приложение не имеющее своего окна и ресурсов размером 2 кБ. Импортирует только три функции две предоставляемые системой Windows и одна написанной нами динамической библиотекой. Как видите подключение созданной нами динамической библиотеки, ничем не отличается от подключения стандартных библиотек Windows. В этом и заключается вся прелесть использования ФАСМ-а, он не берёт на себя слишком много, что в купе с гибким макроязыком позволяет сделать очень многое максимально просто.

Формат исполняемых файлов MS COFF (obj - файлы)

Использование obj-файлов в ФАСМ, лично мне, не кажется жизненно необходимым, однако использование этого формата возможно понадобится при создании проектов на С/С++. Именно на таком примере мы и рассмотрим формат файлов MS COFF.

Для примера напишем программу, выводящую МессаджБокс с текущей датой. Модуль на ассемблере будет составлять строку символов, а модуль на С++ будет выводить эту строку в МессаджБокс.

Вот модуль на ассемблере:

Код (Text):

1.  
2. format MS COFF
3. ;public _WinMainCRTStartup
4. public _outs
5. public ?Wind@@YAPADXZ
6. extrn '__imp__GetLocalTime@4' as GetLocalTime:dword
7. include 'include\kernel.inc'
8. include 'include\macro\stdcall.inc'
9. include 'c:\fasm135\include\lib\strings.mac'
10. include 'c:\fasm135\include\lib\strings.asm'
11. section '.text' code readable executable
12.  ; _WinMainCRTStartup:
13. proc ?Wind@@YAPADXZ
14.     enter
15.     push    ebx esi edi
16.     invoke   GetLocalTime,Date
17.     mov      ebx,_outs
18.     StringCopyHTML ebx,day
19.     add      ebx,eax
20.     xor      eax,eax
21.     mov      ax,[Date.wDay]
22.     stdcall  IntToString,h4,eax
23.     StringCopyHTML ebx,h4
24.     add      ebx,eax
25.     StringCopyHTML ebx,mon
26.     add      ebx,eax
27.     xor      eax,eax
28.     mov      ax,[Date.wMonth]
29.     stdcall  IntToString,h4,eax
30.     StringCopyHTML ebx,h4
31.     add      ebx,eax
32.           StringCopyHTML ebx,year
33.     add      ebx,eax
34.     xor      eax,eax
35.     mov      ax,[Date.wYear]
36.     stdcall  IntToString,h4,eax
37.     StringCopyHTML ebx,h4
38.     add      ebx,eax
39.     mov      eax,_outs
40.     pop edi esi ebx
41.     return
42. section '.data' data readable writeable
43.   h4    db 'Сообщение',0
44.   Date SYSTEMTIME
45.   day db 'День:',0
46.   mon db ' Месяц:',0
47.   year db ' Год:',0
48.   _outs: times 30 db 0

Обратите внимание на строку 2, где закомментировано определение точки входа в программу (_WinMainCRTStartup)если эту строку раскомментировать, то точка входа в программу будет именно в модуле на ассемблере. Результат работы функции записывается в переменную _outs и адрес (указатель на строку) возвращаем в регистре еах. В этом модуле используются макросы копирования строки в строку (StringCopyHTML ebx,day). Этот макрос не входит в поставку компилятора и содержится в файлах strings.mac и strings.asm он просто копирует строку (не включая нулевой символ), указатель на которую передаётся вторым параметром, в строку, указатель которой передаётся вторым параметром, после его выполнения в регистре еах количество скопированных символов. Эта процедура выдаёт строку типа: "День: 28 Месяц: 10 Год:2003". Для использования объектного модуля созданного на ассемблере необходимо в проект на С++ добавить созданный нами объектный файл (Project->Add to project->Files. . . в появившемся окне необходимо выбрать тип файлов obj и указать используемый файл). Теперь рассмотрим текст программы на MS Visual C++ 5.0:

Код (Text):

1.  
2. #include &laquo;windows.h&raquo;
3. extern  char *  __cdecl Wind(void);
4. LPSTR cmsk,dat;
5.  
6. int PASCAL WinMain(HANDLE   hInstance,HANDLE hPrevInstance,LPSTR lpszCmdParam,int nCmdShow)
7. {
8.     dat=Wind();
9.     MessageBox(0,dat,dat,MB_OK);
10. }

Здесь ничего сложного: подключаем файл «windows.h», затем объявляем внешнюю процедуру, возвращающую указатель на строку символов с нулём в конце, объявляем переменную dat, как указатель на строку символов, и наконец функция WinMain в которой вызываем нашу функцию (Wind) на ассемблере и выводим результат в мессаджбокс. Внимательный читатель скажет: "Стоп, но в модуле на ассемблере функцию мы объявили как ?Wind@@YAPADXZ, а в модуле на С++ вызываем Wind". Всё правильно. Просто MS Visual C++ 5.0, к объявленным внешним (находящимся в скомпилированных модулях) процедурам добавляет дополнительные символы, для контроля соответствия типов передаваемых результатов из процедуры и переменных в процедуру. Вот краткая структура имени функций формируемых MS Visual C++:

Префикс	Объявленное имя переменной	Разделитель	Тип вызова процедуры	Тип результата	Тип параметров	Постфикс
?	Wind	@@Y	A	PAD	X	Z

Причём постфикс изменяется в зависимости от наличия передаваемых в функцию параметров. Если параметры передаются, то постфикс "@Z", а если параметры не передаются то просто "Z".

Типы вызова процедуры следующие:

__cdecl	A
__fastcall	I
__stdcall	G

Типы результата и передаваемых переменных имеют одинаковые обозначения:

Тип результата	Размер	Обозначение
char	1	D
unsigned char	1	E
short	2	F
unsigned short	2	G
enum	2	?AW4__unnamed@@
long	4	J
unsigned long	4	K
int	4	H
unsigned int	4	I
float	4	M
double	8	N
long double	10	O
bool	1	_N

Причём если передаётся (получается) не параметр, а его адрес (например char *) то перед обозначением переменной добавляется PA. Если параметры, получаемые из процедуры или передаваемые в процедуру, отсутствуют, вместо них ставится X.

Читатель может сказать: "Это как же нужно мозг морщить, чтобы всё запомнить и не перепутать ничего при составлении имени процедуры?". Такая работа имеет основное свойство: она не особо интеллектуальна, но муторна и действия при её решении вполне укладываются в рамках алгоритма. Отсюда вывод: компьютер на то и создан, что бы выполнять подобные задачи так пусть сам, и добавляет все эти префиксы, постфиксы и т.п. Напишем макрос, который будет объявлять процедуру составляя её имя из имени которое мы ему передаём и добавляя к нему все необходимые префиксы.

Использовать переменные длиннее 4 байт мы не будем, но думаю Вы сами сможете модернизировать макросы под свои нужды если понадобится.

Для начала мы должны определить символьные константы, соответствующие типам вызова процедуры и типам получаемых и возвращаемых параметров:

Код (Text):

1.  
2. ; константы типов вызовов процедур
3. __cdecl fix A
4. __fastcall fix I
5. __stdcall fix G
6. ; константы типов переменных
7. void fix X
8. char$ fix PAD
9. char  fix D
10. unsigned_char$ fix PAE
11. unsigned_char fix E
12. short$ fix PAF
13. short fix F
14. unsigned_short$ fix PAG
15. unsigned_short fix G
16. long$ fix PAJ
17. long fix J
18. unsigned_long$ fix PAK
19. unsigned_long fix K
20. int$ fix PAH
21. int fix H
22. unsigned_int$ fix PAI
23. unsigned_int fix I
24. float$ fix PAM
25. float fix M

Далее следует определение макроса:

Код (Text):

1.  
2. macro exp_proc calltype,returns,name,[arg,type]
3. {
4. dr fix
5. forward
6.  dr fix dr#type
7.  common
8. if type eq void
9. public ?#name#@@Y#calltype#returns#dr#Z
10. ?#name#@@Y#calltype#returns#dr#Z:
11. else
12. public ?#name#@@Y#calltype#returns#dr#@Z
13. ?#name#@@Y#calltype#returns#dr#@Z:
14. end if
15. common
16.  virtual at ebp+8
17.     if ~ arg eq
18.    forward
19.      local ..arg
20.      ..arg dd ?
21.      arg equ ..arg
22.    common
23.      end if
24.      ..ret = $ - (ebp+8)
25.     end virtual
26.     local ..dynamic_data,..dynamic_size
27.     dynamic_data equ ..dynamic_data
28.     dynamic_size equ ..dynamic_size
29.     virtual at ebp - dynamic_size
30.      dynamic_data:
31. }

В первой строке мы очищаем временную символьную константу, далее следует указание препроцессору обработать строку "dr fix dr#type" для всех значений параметров type начиная с первого. Эта строчка, просто создаёт константу содержащую все символы соответствующие всем получаемым процедурой параметрам. Например если в процедуру передаётся два параметра типа int, то dr будет эквивалентно HH. Далее следует указание препроцессору следующие строки обработать только один раз (common) в этих строках мы делаем видимой из других модулей программы метку (название) нашей процедуры и собственно следует содержимое макроса proc, рассмотренного ранее.

Полагаю, этот макрос не должен вызвать затруднений. Сложности в понимании может вызвать только строка "?#name#@@Y#calltype#returns#dr#@Z", объясню её более подробно. Сперва стоит знак вопроса (посмотрите табличку со структурой имени процедуры), после которого, значок номера (#), он говорит препроцессору, что далее следует символьная константа, которую следует склеить в одну метку с предыдущим текстом. Если константы с указанным именем не существует, то она включается, как есть. Рассмотрим последовательность действий препроцессора. Метка состоит из вопросительного знака, затем (без разделителей) добавляется, передаваемая макросу переменная name, после неё добавляется текст @@Y,после текста добавляется передаваемая макросу переменная calltype, затем переменная returns, потом составленная нами константа dr, и наконец постфикс @Z (или просто Z, если в процедуру не передаются параметры).

Всё. Макрос создан. Однако это ещё не всё. С таким определением процедуры не всегда можно использовать стандартные макросы enter и return т.к. тип вызова __cdecl предполагает, что стек после завершения работы процедуры будет очищаться вызывающей процедурой т.е. модулем написанным на С++, а стандартный макрос return сам очищает стек. Вот макрос, содержащий эпилог процедуры для типа вызова __cdecl:

Код (Text):

1.  
2. macro cdecl_ret
3.     {
4.       sub   ebp,dynamic_size
5.       mov     esp,ebp
6.       pop     ebp
7.       ret
8.     }

Но не только эпилог нужно изменить, но и пролог тоже:

Код (Text):

1.  
2. macro cdecl_enter
3.     {
4.       dynamic_size = $ - dynamic_data
5.         end virtual
6.         push  ebp
7.         mov   ebp,esp
8.         add   ebp,dynamic_size
9.     }

Полагаю эти два коротеньких макроса не вызовут затруднений.

Ну и пример использования данных макросов:

Код (Text):

1.  
2. exp_proc __cdecl,char$,Wi,first,int,second,int
3.  cdecl_enter
4.    push ebx esi edi
5.    mov    eax,[first]
6.    stdcall IntToString, _outs,eax
7.    mov    eax,_outs
8.    pop  edi esi ebx
9.  cdecl_ret

Функция IntToString преобразует 32-х битное без знаковое число (второй параметр) в строку (адрес строки передаётся первым параметром).

Модуль на С++ будет выглядеть следующим образом:

Код (Text):

1.  
2. #include <windows.h>
3. extern  char * __cdecl Wind(void);
4. extern  char * __cdecl Wi(int c,int b);
5. LPSTR cmsk,dat;
6. int PASCAL WinMain(HANDLE   hInstance,HANDLE   hPrevInstance,LPSTR    lpszCmdParam,int      nCmdShow)
7. {
8.     dat=Wi(12,30);
9.     MessageBox(0,dat,dat,MB_OK);
10.     Wind();
11. MessageBox(0,dat,dat,MB_OK);
12. }

Думаю больше пояснений не нужно.

Формат исполняемых файлов MS DOS
Формат исполняемых файлов MZ

Программирование под ДОС в ФАСМ в принципе почти ничем не отличается от программирования под ДОС в любом другом компиляторе.

Вот простейший пример программы:

Код (Text):

1.  
2. format MZ
3.     push    cs
4.     pop ds
5.     mov ah,9
6.     mov dx,hello
7.     int 21h
8.     mov ax,4C00h
9.     int 21h
10. hello db 'Hello world!',24h

Как видите ничего сложного.

Формат исполняемых файлов СОМ

Если директива format не указана создаются файлы формата *.сом. Вот пример:

Код (Text):

1.  
2. org 100h        ;Указание загрузить программу начиная с адреса 100h
3. use16       ;Создавать 16-ти битный код
4.         mov ah,9
5.         mov dx,hello
6.         int 21h
7.         int 20h
8. hello db 13,10,'Привет всем$'

Думаю здесь всё понятно. © pas